/*
RunningLoops.dm

This file contains code that makes running possible.

Definitions:
    WALKING - The number (2) next to this defines how many ticks it takes to take another step while walking.
    RUNNING - The number (0) next to this defines how many ticks it takes to take another step while running.
    TIME2RUN - The number(30) next to this defines how long it takes to start running.

Move():
    First it checks if you are already moving.  If so, it stops you.
    Then it sets your moving var to TRUE.
    Then it changes your icon state depending on if you are running or walking.
    Then it does the normal action.  It uses an if() statement to see if the movement succeeded.
        If it did(Meaning you cant start running by walking against a wall), then if does its checks and actions.
        Touching this part isn't necessary, as it doesn't control anything that should need changing.
        Touch it at your own risk.  I'm not fixing it if it breaks.
    If the movement failed, then it sets your moving to FALSE and returns so you can try to move again.


base_EventCycle():
    This is a proc found in Deadron's EventLoop library.  Download it if you do not have it, or you will get errors.
    This is 4 lines of code that controls your running completely.  It runs every tick(1/10 of a second). It checks to see
        if you can run or not.  Touch this at your own risk. This uses TIME2RUN a few times, and that is all you should change.
*/




#define WALKING 2
#define RUNNING 0
#define TIME2RUN 30

mob{
    var{
        tmp{
            moving = FALSE
            walk_time = 0
            steps = 0
            move = WALKING
        }
    }
    Move(){
        if(moving) return FALSE
        moving=TRUE
        if(move==RUNNING) icon_state="Run"
        if(move==WALKING) icon_state=""
        . = ..()
        if(.)
            steps++
            var/s=steps
            spawn(move)
                moving=FALSE
            spawn(5)
                if(s==steps)
                    walk_time=0
                    steps=0
                if(move==RUNNING && walk_time <= TIME2RUN) icon_state=""
        else
            moving=FALSE
            return FALSE
    }
    base_EventCycle(){
        if(moving)
            walk_time++
        if(move==WALKING && walk_time>=TIME2RUN)
            move=RUNNING
        else if(move==RUNNING && walk_time<=TIME2RUN)
            move=WALKING
    }
}