//definitions:

//set these to your icon size for your project
#define TILE_WIDTH 32
#define TILE_HEIGHT 32

//set these to your desired limitations for your project. 1#INF means that your project has no limit on this axis.
//TILES is view_width * view_height, or the viewport area.

#define MAXIMUM_VIEW_TILES 1200
#define MAXIMUM_VIEW_WIDTH 1#INF
#define MAXIMUM_VIEW_HEIGHT 1#INF
#define MINIMUM_VIEW_WIDTH 1
#define MINIMUM_VIEW_HEIGHT 1

//These add extra tiles to all four sides of the viewport.
//These are useful for if you need to use effects like screen shake.
#define EXTRA_VIEW_WIDTH 0
#define EXTRA_VIEW_HEIGHT 0

//rounds up
#define ceil(x) (-(round(-x))

client
    var
        map_width //width of the map in pixels
        map_height //height of the map in pixels

        view_width //width of the viewport in tiles
        view_height //height of the viewport in tiles
        view_zoom //stores the current zoom size of the default map.

client
    verb
        //This proc is called automatically on client login and should be called by :map.on-resize in your dmf file.

        onMapResize(map as text, default as num, width as num, height as num, zoom as num)
            set instant = 1, hidden = 1

            if(default)
                //update the client map metrics
                map_width = width
                map_height = height
                view_zoom = 0

                //attempt to find the first zoom level that obeys our screen limitations
                do
                    //increase zoom level by 1
                    ++view_zoom

                    //divide the map width by the zoomed tile size to get the number of tiles that fit on the screen. We round up because empty space is bad.
                    view_width = ceil(map_width / (TILE_WIDTH * view_zoom))

                    //if the tile width is even, add one tile to make it odd so the map is centered properly
                    if(view_width%2==0)
                        ++view_width

                    //now do the same thing for the height.
                    view_height = ceil(map_height / (TILE_HEIGHT * view_zoom))
                    if(view_height%2==0)
                        ++view_height

                while(view_width>MAXIMUM_VIEW_WIDTH || view_height> MAXIMUM_VIEW_HEIGHT || view_width*view_height>MAXIMUM_VIEW_TILES)

                //now that we've found a view size that works, we add the extra width and height, and apply the minimum limits.
                view_width = max(MINIMUM_VIEW_WIDTH,view_width)+EXTRA_VIEW_WIDTH*2
                view_height = max(MINIMUM_VIEW_HEIGHT,view_height)+EXTRA_VIEW_HEIGHT*2

                //And then update the client's view size
                view = "[view_width]x[view_height]"

                //and if the zoom level changed, we tell the client to update it
                if(zoom!=view_zoom)
                    winset(src,map,"zoom=[view_zoom]")

client
    proc
        //call on client creation, or when changing the default map. It's set waitfor 0 so that the calling proc doesn't wait around on the winget() to finish before continuing.
        updateMapSize()
            set waitfor = 0
            //get the parameters from the default map element that our resize function expects.
            var/list/params = params2list(winget(src,":map","id;size.x;size.y;zoom"))

            //now call the resize verb manually using this data.
            onMapResize(params["id"],1,text2num(params["size.x"]),text2num(params["size.y"]),text2num(params["zoom"]))

    New()
        . = ..()
        updateMapSize()