proc/RotateBlock(turf/loc1, turf/loc2, dir)
    if(loc1.z != loc2.z)                  return 0 // WARNING: Requires a 2-dimentional square.
    if(dir != -1 && dir != 1 && dir != 2) return 0 // WARNING: Requires dir to be 1  (clockwise)
                                                   //                            -1  (counter-clockwise)
                                                   //                          or 2. (full turn)
    var/Top    = max(loc1.y, loc2.y)
    var/Bottom = min(loc1.y, loc2.y)
    var/Right  = max(loc1.x, loc2.x)
    var/Left   = min(loc1.x, loc2.x)
    
    var/Height =   Top - Bottom + 1
    var/Width  = Right - Left   + 1
    
    if(Height != Width) return 0                   // WARNING: Requires a perfect square.
    
    var/list/Turfs  = block(loc1, loc2)
    var/list/RefA = list()
    var/list/RefB = list()
    
    var/Z = loc1.z
    for(var/turf/T in Turfs)
        var/X = T.x  // Destination locations.
        var/Y = T.y
        
        var/FromLeft   =   T.x - Left   // Relative locations.
        var/FromBottom =   T.y - Bottom
        var/FromRight  = Right - T.x
        var/FromTop    =   Top - T.y
        
        if(dir == 1)
            X = FromBottom + Left
            Y = FromRight + Bottom
        else if(dir == -1)
            X = FromTop + Left
            Y = FromLeft + Bottom
        else if(dir == 2)
            X = FromRight + Left
            Y = FromTop + Bottom
        
        for(var/atom/movable/A in T)
            RefA += A
            RefB += locate(X, Y, Z)
    
    for(var/I = 1 to length(RefA))
        var/atom/movable/A = RefA[I]
        A.loc = RefB[I]
    
    return 1