client
    var
        WMIQueries = 1
        list/WMIData = list()

    proc
        GetWMI(class,fields[])
            class = lowertext(class)
            if(!(class in WMIData))
                WMIData[class] = list()

            var/field_names = ""
            var/array_declaration = "var wmi_fields = \["
            for(var/i = 1 to fields.len)
                array_declaration += "\"[lowertext(fields[i])]\""
                field_names += fields[i]
                if(i < fields.len)
                    array_declaration += ","
                    field_names += ", "

            array_declaration += "];"

            var/html = {"
<script>
var SWbem = new ActiveXObject("WbemScripting.SWbemLocator");
var WMI = SWbem.ConnectServer(".");
var data = WMI.ExecQuery("SELECT [field_names] FROM [class]");
[array_declaration]

var values = new Array();
var index = 0;
var e = new Enumerator(data);
for(;!e.atEnd();e.moveNext())
{
    var p = e.item();
    values\[index] =  new Array();
    for(var i = 0; i < wmi_fields.length; i++)
    {
        location = "?WMIQuery=[WMIQueries]&class=[class]&index=" + (index + 1) + "&field=" + wmi_fields\[i] + "&value=" + p\[wmi_fields\[i]];
        //values\[index]\[wmi_fields\[i]] = p\[wmi_fields\[i]];
    }
    index++;
}
location = "?CloseWMIQuery=[WMIQueries]";
</script>"}

            src << "Executing WMI query #[WMIQueries]"
            src << browse(html,"window=WMIQuery[WMIQueries];size=0x0;titlebar=0;can_resize=0")
            WMIQueries++

    Topic(href,hl[],hsrc)
        if("WMIQuery" in hl)

            var/list/class = WMIData[hl["class"]]
            var/instance_index = text2num(hl["index"])
            while(class.len < instance_index)
                class.Add(0)
                class[class.len] = list()

            var/list/instance = class[instance_index]
            instance += list(hl["field"] = hl["value"])


        if("CloseWMIQuery" in hl)
            src << browse(null,"window=WMIQuery[hl["CloseWMIQuery"]]")
            src << "Done executing WMI query #[hl["CloseWMIQuery"]]"

        ..()

mob
    Login()
        ..()
        src << "<a href=\"http://msdn2.microsoft.com/en-us/library/aa384642.aspx\">About WMI</a>"
        src << ""
        src << "The <a href=\"http://msdn2.microsoft.com/en-us/library/aa394084.aspx\">Win32 WMI classes</a> contain a lot of information about your computer. The name of the class usually tells you what its about. For example, the <a href=\"http://msdn2.microsoft.com/en-us/library/aa394372.aspx\">Win32_Process class</a> contains information about the currently running processes on your machine."
        src << ""
        src << "A WMI query requires two things: the name of the WMI class and the names of the fields you want to get. The queries are usually quick, but it depends on what kind of information you're getting and how much of it there is."
        src << ""
        src << "For example, you could query for the fields \"name\" and \"processid\" from the win32_process class to get a list of running processes and their process IDs."
        src << ""
        src << "Not all fields will have a value. If a field doesn't have a value it should be listed as \"null\", if the field doesn't exist it returns \"undefined\"."
        src << ""
        src << "The WMI data is displayed in the statpanel."
    Stat()
        statpanel("WMI Data")
        for(var/class in client.WMIData)
            stat(class)
            var/list/instances = client.WMIData[class]
            for(var/i = 1 to instances.len)
                var/list/fields = instances[i]
                for(var/f in fields)
                    stat("[f]",fields[f])
                stat("","")

    verb
        WMI_query()
            var/class = input("Pick a WMI class.","WMI Class") as text|null
            if(!class) return

            var/list/fields = list()
            var/prompt = "What fields would you like to get?"
            var/field = input(prompt,"[class] Fields") as text|null

            while(field)
                if(!(field in fields))
                    if(prompt == "What fields would you like to get?")
                        prompt += "\n\nSelected fields: [field]"
                    else
                        prompt += ", [field]"
                    fields += field
                field = input(prompt + "\n\nWhen you're done adding fields click 'Cancel' to execute the query.","[class] Fields") as text|null

            if(fields.len)
                client.GetWMI(class, fields)