Polatrite's site

Looking for spell/visual effects artist (paid $10-30 per asset)

Thu, 16 May 2013 20:10:51 +0000

Hello,

I'm an experienced BYOND developer working on a new project with the working title "MiniMMO". It's a hack and slash RPG with an emphasis on tons of area-of-effect combat and the killing of huge quantities of enemies (fights of 10-15~ enemies solo)

I'm currently looking for a spell/visual effects artist that can help create visuals for abilities in the game. If you have the animation talent and interest in working on creatively designing ways to blow enemies up, I'd love to pay you cash money.

Please include a link to your portfolio or past work and email me at polatrite gmail com.

While we'll work out details of payment on a per-asset basis, here are some of my general guidelines:

$10 - Simple projectile effects with medium to high frames (5-8 frames); short range circular AOEs with low frames (2-3 frames); party/personal buffs

$20 - Medium to long range circular AOEs with low to high frames, based on complexity; much more complex projectiles such as those that split, swirl and explode; terrain enhancements such as circles of healing, etc.

$30 - Complex AOEs in any number of shapes (cone, line, circle, etc.); complex effects like blizzards or tornados

All payments will be timely and made via PayPal. Please have your own personal account, not a parent or friend.

Thanks for reading!

Edit: A wild gameplay video appears! http://www.twitch.tv/polatrite/c/2297661

(warning, unedited)

How-to: Teleport your players to new maps

Sat, 20 Apr 2013 20:09:55 +0000

Every game needs teleporters. They make everything better.

Especially in BYOND, teleporters are among the most popular turfs in the game - whether you make the edge of one map take you seamlessly to the edge of another, or if you actually have teleporters and portals, they're pretty useful.

It's not readily apparent how to use teleporters with the library though. Try this!

turf
    teleporter
        icon_state = "blue spin"
        var
            destx
            desty
            destz

        Entered(mob/M)
            if(istype(M))
                if(!M.key)
                    return
                spawn(0)
                    if(destx && desty && destz)
                        var/turf/T = locate(destx,desty,destz)
                        set_pos(T.px, T.py, 0, T.z)
                    else
                        M << "Teleporter failed, destination not set!"

Now all you need to do is place a teleporter turf on the map, then right-click and Edit it. Set the destx, desty, destz properties to the location you would like it to teleport you to.

How-to: Spark/Charged Bolt style 'random lightning sparks' effect

Sat, 20 Apr 2013 02:21:12 +0000

Do you remember the Charged Bolt from Diablo 2, or the Spark effect from the more recent Path of Exile? Shockbolts in Torchlight 2?

I could probably continue naming games with this iconic ability. Instead, let's get some code!

First, create a new projectile:

projectile
    random_sparks
        damage = 15
        icon_state = "spark"

        pwidth = 20
        pheight = 16
        pixel_x = -6
        pixel_y = -5

        move_speed = 5

        // make it use the MagicCombat object to deal damage
        hit(mob/m)
            MagicCombat.attack(owner, m, damage)

        movement()
            effect("flame", layer = layer - 1)
            . = ..()
            
            var/randx = rand(-1 * move_speed, move_speed)
            var/randy = rand(-1 * move_speed, move_speed)
            
            switch(dir)
                if(NORTH)
                    randy += move_speed/3
                if(SOUTH)
                    randy -= move_speed/3
                if(EAST)
                    randx += move_speed/3
                if(WEST)
                    randx -= move_speed/3
                if(NORTHEAST)
                    randx += move_speed/6
                    randy += move_speed/6
                if(NORTHWEST)
                    randx -= move_speed/6
                    randy += move_speed/6
                if(SOUTHEAST)
                    randx += move_speed/6
                    randy -= move_speed/6
                if(SOUTHWEST)
                    randx -= move_speed/6
                    randy -= move_speed/6
            
            vel_x += randx
            vel_y += randy
            vel_x = max(-1 * move_speed, min(vel_x, move_speed))
            vel_y = max(-1 * move_speed, min(vel_y, move_speed))

Now, add an ability to call your projectile:

Ability
    Spark
        name = "Spark"
        icon_state = "ability-button-fireball"
        description = "Shoots 3 sparks that deal 8 magic damage each."
        animation = "attacking"
        mana_cost = 2
        cooldown = 30

        can_use(mob/user)
            if(user.on_cooldown("spark", "attack"))
                return 0
            else
                return ..()

        effect(mob/user)

            user.cooldown("spark", cooldown)
            user.cooldown("attack", 10)

            for(var/i = 1, i <= 3, i++)
                new /projectile/random_sparks(user, user.target)

            user.noise('spark.wav', frequency = rand(0.7, 1.3))

Fire away!

How-to: Knockback on abilities

Sat, 20 Apr 2013 01:46:25 +0000

Sometimes it's fun to whack a monster and send it flying across the screen. Here's some code to do just that!

First, add this to a new file, or to the bottom of your abilities.dm file.

mob
    proc
        knockback(mob/attacker, strength)
            var/dir = get_dir(attacker, src)
            _push(dir, strength)

        pull(mob/attacker, strength)
            var/dir = get_dir(src, attacker)
            world << "Pulling [src] toward [attacker] at [strength] ([dir]) "
            _push(dir, strength)

        _push(dir, strength)
            switch(dir)
                if(NORTH)
                    vel_y += strength
                if(SOUTH)
                    vel_y += -strength
                if(EAST)
                    vel_x += strength
                if(WEST)
                    vel_x += -strength
                if(NORTHWEST)
                    vel_y += strength * 2/3
                    vel_x += -strength * 2/3
                if(NORTHEAST)
                    vel_y += strength * 2/3
                    vel_x += strength * 2/3
                if(SOUTHWEST)
                    vel_y += -strength * 2/3
                    vel_x += -strength * 2/3
                if(SOUTHEAST)
                    vel_y += -strength * 2/3
                    vel_x += strength * 2/3

Next, go into your abilities.dm file and find the ability you'd like to add knockback to. Check out the effect() proc, it'll look like this:

        effect(mob/user)

            // find a target in the attacker's melee range
            var/mob/target = user.melee_target()

            // trigger a 40 tick cooldown for this ability and
            // a 10 tick cooldown for all attacks
            user.cooldown("melee-attack", cooldown)
            user.cooldown("attack", 10)

            // inflict damage and show a graphical effect on the target
            PhysicalCombat.attack(user, target, 5 + user.power)
            target.effect("dagger-slash")
            target.noise('hit-1.wav', frequency = rand(0.7, 1.3))

Simply add the new call to the method:

            target.knockback(user, 10)

Suddenly, knockback!

Should I release the "Survival: TLE" source code?

Thu, 18 Apr 2013 18:58:48 +0000

I'm probably putting this in the wrong forum, but I wasn't sure which forum to stick it in.

I'm an ancient developer from the olden days (like 2001) and I made several games, including Survival, and the sequel called Survival: The Lost Era. They are pretty cool games, but by the time I released Survival: TLE, I had moved on and gotten pretty busy.

I was wondering if anyone thought it would be a good, bad, or horrendous idea to release the code and assets for the project. 5-10 years ago this would have been an awful thought as there was substantial ripping problems. I remember DB Zeta and several other major leaks which resulted in all kinds of havoc.

Maybe the community (or at least the filtering on the website) has improved such that it's not an awful idea now? What are your thoughts?

MODULE: Health/mana regeneration script

Sat, 30 Jun 2012 12:10:36 +0000

This is a basic script to enable health and mana regeneration. You can configure the % of max that it should restore, as well as how often it restores. It's currently set to restore 1% health and 2% mana per second.

I also included two Conditions that you can apply, Wounded and Sapped, that will prevent health and mana regen respectively.

Constants
    var
        const
            REGEN_HEALTH_PERCENT = 1
            REGEN_MANA_PERCENT = 2

            REGEN_TICK_LENGTH = 10

            // Regen only on players, or monsters too?
            REGEN_ONLY_PLAYERS = 1

world
    New()
        ..()
        spawn() tick_regen()

proc

    tick_regen()
        spawn(Constants.REGEN_TICK_LENGTH)
            tick_regen()

        var/regen

        for(var/mob/M in world)
            if(Constants.REGEN_ONLY_PLAYERS && !M.key)
                continue

            regen = max(1, round(M.max_health * Constants.REGEN_HEALTH_PERCENT / 100))
            if(M.has_condition(/Condition/Wounded))
                regen = 0

            M.gain_health(regen)

            regen = max(1, round(M.max_mana * Constants.REGEN_MANA_PERCENT / 100))
            if(M.has_condition(/Condition/Sapped))
                regen = 0

            M.gain_mana(regen)


Condition

    Wounded
        tick_count = 4
        tick_rate = 40

        icon_state = "wounded"

        tick()
            target.effect("wounded")

    Sapped
        tick_count = 4
        tick_rate = 40

        icon_state = "sapped"

        tick()
            target.effect("sapped")

Supporting the Flash client with a BYOND game

Mon, 19 Dec 2011 17:18:07 +0000

I think as we are drawing closer to a presumed Flash client release date, it would be extremely helpful if somebody in the know could give us a list of the things that are probably NOT going to be possible in the new client.

* Custom interface files won't work - does this mean we get a map/info/output/input panel in the default 3.5 configuration? Map left, info/output right?

* Will any of the mouse functionality be restricted? Of course right-clicking is impossible (unless this has changed in Flash in the last few years), what about some of the more precise drag/drop methods?

* Will fps settings still work as they do currently? Will there be plateaus for fps (e.g. multiples of 5)?

Because we're (hopefully) so close to an early release, I'd really like to ensure my latest work is compatible right out of the gate, especially as it relates to complex GUI interaction with on-screen elements, and I'm sure many other folks are as well.

In addition, this information could be shared in a broader way (blog posts instead of a forum thread) to help set a baseline expectation and quell any potential disappointment from the reduced featureset.

Thanks for reading!

~Polatrite~

Is somebody phishing?

Thu, 29 Sep 2011 19:28:37 +0000

http://dev.byond.com/developer/forum/?action=forum_index

I'm not sure what I accidentally stumbled into, but I input my password into this page. After realizing this forum was drastically out-of-date I immediately changed my password just to be safe.

Is this a legitimate relic of the past or some kind of phising attempt?

~Polatrite~

Library for overriding range()/density/etc for big icons?

Mon, 14 Mar 2011 15:12:17 +0000

I was wondering if anyone has created a library that can be used when your world.icon_size is set to a non-default value.

For example, I created the following project to test out icon_size set to 8.

world
    icon_size = 8

atom
    movable
        var
            density_width = 1
            density_height = 1

mob
    icon = 'base.dmi'
    density = 1

    o1x1
        icon = 'o1x1.dmi'
    o2x1
        icon = 'o2x1.dmi'
        density_width = 2
    o2x2
        icon = 'o2x2.dmi'
        density_width = 2
        density_height = 2
    o3x2
        icon = 'o3x2.dmi'
        density_width = 3
        density_height = 2

Upon testing, I noted that all objects which are dense are only dense in the bottom left corner (somewhat as I expected), additionally all the range()/view()hearers() and similar procs only check for that corner of the mob when listing things in range. So in order to get all my standard functions working properly with this new tile size, I'd have to write several of my own functions to take into account these "larger than a tile" atoms.

Has anyone made a library that does this? I searched around both the resources and forums and couldn't dig anything up.

~Polatrite~

Edit: Just noticed that Shadowdarke's "BigAtom" library WAS updated recently. I'm going to check it and see if it works with world.icon_size that is not 32x32.

world.Export() POST/GET

Thu, 11 Mar 2010 20:39:08 +0000

At the bottom of the reference for world.Export() is this little blurb:
"Note that the HTTP request is submitted using the GET method as opposed to the POST method. Support for POST may be added in the future."

Has any support been added to handle POST yet? :)

~Polatrite~