room/proc/GetHopsTo(room/R)
  var/savefile/S = new(ZONES_DIR + "[zone.name]")
  S["rooms/[src.id]/hops/[R.id]"] >> .


room/proc/GetHops()
  . = 0   // number of changes made as a result of running this proc
  var/dirlist = list("north", "south", "east", "west", "northeast", 
"southeast", "northwest", "southwest", "up", "down")
  var/savefile/S = new(ZONES_DIR + "[zone.name].sav")  // get the room's file
  S.cd = "/rooms/[src.id]/hops/"
  var/V
  var/dir
  var/hops
  var/oldhops
  var/room/R
  var/room/R2
  // explore rooms that are known to be reachable from here
  for(V in S.dir)
    R = mud.LocateRoom(V)     // get a room by ID
    S["[V]"] >> hops
    // verify a neighbor is really a neighbor
    if(hops == 1)
      for(dir in dirlist)
        if(vars[dir] == R) break
      if(!dir)
        ++.
        S:Remove(V)     // that room isn't next door!
        continue
    // explore R's neighbors; each should be at most hops+1 hops away now
    for(dir in dirlist)
      R2 = R.vars[dir]
      if(!R2) continue
      S["[R2.id]"] >> oldhops
      // R's neighbor R2 is not in the explored list, or is already marked as farther away
      if(!oldhops || oldhops > hops + 1)
        ++.
        world << "writing [hops + 1] to [S.cd]([R2.id])"
        S["[R2.id]"] << hops + 1
  // explore immediate neighbors
  for(V in dirlist)
    R = vars[V]
    if(!R || R == src) continue    // don't count non-exits or loopbacks
    S["[R.id]"] >> hops

    // if not recorded or it's listed too far away, mark it as a neighbor (1 hop)
    if(!hops || hops != 1)
      ++.
      S["[R.id]"] << 1